Ugrás a tartalomhoz

Sütibeállítások

Típusonként válassza ki, mely sütiket engedélyezi. Választását bármikor módosíthatja a Sütibeállítások linken, amely minden oldal alján megtalálható. Adatvédelmi nyilatkozat

Szükséges

Mindig bekapcsolva

A bejelentkezéshez, a kosár megőrzéséhez és a választásai megjegyzéséhez szükségesek. Ezek mindig be vannak kapcsolva.

Milyen sütik?
  • weboke_sessie, weboke_klant, weboke_remember: a munkamenet és a bejelentkezve maradás
  • weboke_basket: a kosár
  • wkBtwIncl: az árak megjelenítése ÁFÁ-val vagy anélkül
  • wok_cookies: a sütiválasztás, 12 hónap

Méri, melyik hirdetés vezet látogatáshoz vagy rendeléshez, hogy ne fizessünk hatástalan hirdetésekért.

Milyen sütik?
  • Google Ads a Google Tag Manageren keresztül (_gcl_au, _gcl_aw), legfeljebb 90 napig
  • OpenAI Ads, hirdetések a ChatGPT-ben
  • wok_aff: melyik partnerünk ajánlására érkezett (partnerprogram), 60 nap

4,6

Ország és nyelv

Minden országnak saját oldala van, az adott ország áraival és ÁFA-jával.

Megtekintés

De top 5 per categorie laten zien

Ez a cikk még nincs lefordítva. Ön a holland nyelvű verziót olvassa.

De best verkopende producten per afdeling, de grootste klanten per regio, de drukste dagen per maand: je wilt niet de top 5 van de hele lijst, maar de top 5 binnen één categorie. GROOTSTE werkt op de hele kolom en geeft bij gelijke bedragen twee keer hetzelfde product. In Euro-Office los je dit op met één formule.

Als voorbeeld nemen we de jaaromzet per product van Bloemisterij Het Zonnetje: in kolom A het product, in B de categorie (Rozen, Tulpen, Planten) en in C de omzet, van rij 2 tot en met 18. In F1 staat de categorie die je wilt zien: Rozen.

De top 5 in één formule

Typ in H2:

=NEMEN(SORTEREN(FILTER(A2:C18;B2:B18=F1);3;-1);5)

Lees hem van binnen naar buiten:

  1. FILTER(A2:C18;B2:B18=F1) houdt alleen de rijen van de categorie in F1 over, met alle drie de kolommen.
  2. SORTEREN(...;3;-1) sorteert die rijen op de derde kolom (de omzet), van hoog naar laag (-1).
  3. NEMEN(...;5) houdt de bovenste 5 rijen over.

Druk op Enter: de vijf producten met categorie en omzet verschijnen in H2 tot en met J6. Typ je in F1 Planten, dan verandert de lijst meteen.

De top 5 van de categorie Rozen
De categorie staat in F1 (1). SORTEREN sorteert op de kolom Omzet (2). In F2:G6 de vijf hoogste bedragen per categorie met GROOTSTE en FILTER, in H2:J6 de hele top 5 met NEMEN, SORTEREN en FILTER

Gelijke bedragen zijn geen probleem: in het voorbeeld hebben Grand Prix en Ecuadoriaanse roos allebei 3.400 omzet, en beide staan in de lijst. Bij twee keer GROOTSTE met INDEX en VERGELIJKEN zou twee keer Grand Prix verschijnen.

Alleen de bedragen, per categorie naast elkaar

Wil je alleen de vijf hoogste bedragen, bijvoorbeeld voor meerdere categorieën naast elkaar, gebruik dan GROOTSTE op een gefilterde lijst. Zet de categorieën in F1, G1 en verder, selecteer F2:G6, typ:

=ALS.FOUT(GROOTSTE(FILTER($C$2:$C$18;$B$2:$B$18=F$1);RIJEN($1:1));"")

en druk op Ctrl+Enter. FILTER houdt alleen de bedragen van de categorie in rij 1 over. RIJEN($1:1) is in de eerste rij 1 en wordt in de rijen eronder 2, 3, 4 en 5: de grootste, de op een na grootste enzovoort. ALS.FOUT laat de cel leeg als een categorie minder dan vijf producten heeft; Tulpen heeft er maar vier.

Let op: op Excel-sites staat vaak =GROOTSTE(ALS($B$2:$B$18=F$1;$C$2:$C$18);RIJEN($1:1)). Die geeft in Euro-Office met gewoon Enter een verkeerde uitkomst: ALS kijkt dan niet naar de hele kolom, zodat je de grootste bedragen van álle categorieën krijgt of #NUM!. Sluit je hem af met Ctrl+Shift+Enter, dan krijgt de formule accolades {…} en klopt de uitkomst wel. FILTER zoals hierboven is eenvoudiger.

Alleen het hoogste bedrag

Voor één getal is het eenvoudiger: =MAX.ALS.VOORWAARDEN(C2:C18;B2:B18;F1) geeft de hoogste omzet binnen de categorie, hier 6.150.

Valkuilen

  • Minder dan 5 producten in een categorie: zonder ALS.FOUT geeft GROOTSTE #NUM! bij de rijen die er niet zijn. NEMEN heeft er geen last van en toont gewoon minder rijen.
  • De formule met NEMEN blijft leeg: er staat iets in de 5 rijen en 3 kolommen waar de uitkomst naartoe wil. Zie Lijsten die zichzelf bijwerken met FILTER, UNIEK en SORTEREN.
  • Een collega met Excel 2019 of ouder ziet bij NEMEN, SORTEREN en FILTER #NAME?.

Egy pillanat…

Domainek beállítása

Állítsa be domainenként a névszervereket, a tárhelyhez való kapcsolást és azt, hogy ki legyen a tulajdonos.

Domainek betöltése…