Ugrás a tartalomhoz

Sütibeállítások

Típusonként válassza ki, mely sütiket engedélyezi. Választását bármikor módosíthatja a Sütibeállítások linken, amely minden oldal alján megtalálható. Adatvédelmi nyilatkozat

Szükséges

Mindig bekapcsolva

A bejelentkezéshez, a kosár megőrzéséhez és a választásai megjegyzéséhez szükségesek. Ezek mindig be vannak kapcsolva.

Milyen sütik?
  • weboke_sessie, weboke_klant, weboke_remember: a munkamenet és a bejelentkezve maradás
  • weboke_basket: a kosár
  • wkBtwIncl: az árak megjelenítése ÁFÁ-val vagy anélkül
  • wok_cookies: a sütiválasztás, 12 hónap

Méri, melyik hirdetés vezet látogatáshoz vagy rendeléshez, hogy ne fizessünk hatástalan hirdetésekért.

Milyen sütik?
  • Google Ads a Google Tag Manageren keresztül (_gcl_au, _gcl_aw), legfeljebb 90 napig
  • OpenAI Ads, hirdetések a ChatGPT-ben
  • wok_aff: melyik partnerünk ajánlására érkezett (partnerprogram), 60 nap

4,6

Ország és nyelv

Minden országnak saját oldala van, az adott ország áraival és ÁFA-jával.

Megtekintés

Havi vagy időszakos árbevétel összegzése a SZUMHATÖBB függvénnyel

A pénztárkönyvben, értékesítési listában vagy munkaidő-nyilvántartásban minden sorhoz tartozik egy dátum. Amire kíváncsi, az a havi, negyedéves vagy két dátum közötti összeg, esetleg termékenként is. A SZUMHATÖBB függvénnyel és két dátumfeltétellel ilyen összesítést készíthet, amely új sorok hozzáadásakor is helyes marad. Kimutatással is megoldható (lásd: Kimutatás tábla havi, negyedéves vagy heti bontásban), de a SZUMHATÖBB praktikusabb, ha az összesítésnek állandó formában kell maradnia, például egy jelentéshez vagy költségvetéshez.

Példaként a Bloemisterij Het Zonnetje értékesítési adatait vesszük a Verkoop munkalapon: az A oszlopban a dátum, a B-ben a termék, a C-ben a kategória, a D-ben pedig az összeg szerepel, a 2. sortól a 300. sorig.

1. lépés: a hónapok sora

Hozzon létre egy Összesítés munkalapot. Ahelyett, hogy tizenkét dátumot gépelne be, egyetlen képlet mindet létrehozza. Írja be az A2 cellába:

=KALK.DÁTUM(DÁTUM(2026;1;1);SORSZÁMLISTA(12;1;0))

A SORSZÁMLISTA(12;1;0) a 0 és 11 közötti számokat állítja elő, a KALK.DÁTUM pedig ennyi hónapot ad hozzá 2026. január 1-jéhez. Így minden hónap első napját megkapja az A2 és A13 közötti cellákban. Adja meg az A2:A13 tartománynak az éééé. hhhh egyéni formátumot (a Több formátum, Egyéni útvonalon, lásd: Egyéni számformátumok: „12 db”, összegek ezrekben, piros szín negatív értéknél), és ekkor 2026. január, 2026. február stb. jelenik meg.

Az éééé. hhhh dátumformátum
Az éééé. hhhh egyéni formátum a hónapot teljes névvel, az évvel együtt jeleníti meg

2. lépés: a havi árbevétel

Írja be a B2 cellába:

=SZUMHATÖBB(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&HÓNAP.UTOLSÓ.NAP($A2;0))

A SZUMHATÖBB azokat az összegeket adja össze, amelyeknél a dátum nagyobb vagy egyenlő a hónap első napjánál, és kisebb vagy egyenlő az utolsó napjánál (a HÓNAP.UTOLSÓ.NAP 0 értékkel ugyanannak a hónapnak a végét adja). Húzza le a képletet a B13 celláig, vagy jelölje ki a B2:B13 tartományt a gépelés előtt, és a bevitelt a Ctrl+Enter billentyűkombinációval zárja le.

3. lépés: termékenként

Írja a termékneveket fejlécként egymás mellé, például Rozen a C1, Tulpen a D1 és Boeket az E1 cellába, majd írja be a C2 cellába:

=SZUMHATÖBB(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&HÓNAP.UTOLSÓ.NAP($A2;0);Verkoop!$B$2:$B$300;C$1)

Egy újabb feltételpár kerül a képletbe: a terméknek meg kell egyeznie a fejléccel. Figyeljen a dollárjelekre: a $A2 a hónapok oszlopát rögzíti, a C$1 a fejlécek sorát. Így ugyanaz a képlet állhat a teljes tartományban. Gyors megoldás: először jelölje ki a C2:E13 tartományt, írja be a képletet, és nyomja meg a Ctrl+Enter billentyűkombinációt. Az Euro-Office ekkor az összes kijelölt cellába beírja a képletet, a hivatkozásokat cellánként igazítva.

Árbevétel havonta és termékenként
Havonta és termékenként összegezve. A szerkesztőlécen a C2 cella képlete látható, amely a C$1 hivatkozással a Rozen fejlécre (1) mutat

Darabszám összeg helyett

A havi eladások számát ugyanezekkel a feltételekkel, a DARABHATÖBB függvénnyel számolhatja meg:

=DARABHATÖBB(Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&HÓNAP.UTOLSÓ.NAP($A2;0))

Tetszőleges időszak

Írjon egy kezdő dátumot a H1, egy záró dátumot pedig az I1 cellába. A kettő közötti árbevétel, mindkét napot beleszámítva:

=SZUMHATÖBB(Verkoop!D:D;Verkoop!A:A;">="&H1;Verkoop!A:A;"<="&I1)

Buktatók

  • Idézőjelek és &: az összehasonlítás idézőjelek közé kerül, a cellát pedig & jellel kell utána fűzni: ">="&H1. Ha ">=H1" formában írja be, az Euro-Office a H1 szöveget keresi, és az eredmény 0 lesz.
  • Időpontot is tartalmazó dátumok (16-11-2026 14:32) a hónap utolsó napján kimaradnak a "<="&HÓNAP.UTOLSÓ.NAP(...) feltételből, mivel az éjfélt jelent. Ilyenkor második feltételként használja a "<"&KALK.DÁTUM($A2;1) kifejezést: kisebb, mint a következő hónap első napja.
  • Csak a hónap sorszáma szerinti szűrés, például a HÓNAP() függvénnyel egy segédoszlopban, a 2025. januárt és a 2026. januárt együtt számolja. Az évet mindig vegye figyelembe.
  • Szövegként tárolt dátumok nem számítanak bele. Lásd: Dátumok, amelyek szövegként érkeznek, vagy amelyeknél a nap és a hónap fel van cserélve.

Egy pillanat…

Domainek beállítása

Állítsa be domainenként a névszervereket, a tárhelyhez való kapcsolást és azt, hogy ki legyen a tulajdonos.

Domainek betöltése…