Ugrás a tartalomhoz

Sütibeállítások

Típusonként válassza ki, mely sütiket engedélyezi. Választását bármikor módosíthatja a Sütibeállítások linken, amely minden oldal alján megtalálható. Adatvédelmi nyilatkozat

Szükséges

Mindig bekapcsolva

A bejelentkezéshez, a kosár megőrzéséhez és a választásai megjegyzéséhez szükségesek. Ezek mindig be vannak kapcsolva.

Milyen sütik?
  • weboke_sessie, weboke_klant, weboke_remember: a munkamenet és a bejelentkezve maradás
  • weboke_basket: a kosár
  • wkBtwIncl: az árak megjelenítése ÁFÁ-val vagy anélkül
  • wok_cookies: a sütiválasztás, 12 hónap

Méri, melyik hirdetés vezet látogatáshoz vagy rendeléshez, hogy ne fizessünk hatástalan hirdetésekért.

Milyen sütik?
  • Google Ads a Google Tag Manageren keresztül (_gcl_au, _gcl_aw), legfeljebb 90 napig
  • OpenAI Ads, hirdetések a ChatGPT-ben
  • wok_aff: melyik partnerünk ajánlására érkezett (partnerprogram), 60 nap

4,6

Ország és nyelv

Minden országnak saját oldala van, az adott ország áraival és ÁFA-jával.

Megtekintés

Önmagukat frissítő listák a SZŰRŐ, EGYEDI és SORBA.RENDEZ függvénnyel

Ügyféllista ismétlődések nélkül, az összes nyitott rendelés áttekintése, terméklista forgalom szerinti sorrendben: korábban az ilyen listákat másolással, szűréssel és rendezéssel készítettük, és minden változás után újra el kellett végezni a munkát. A SZŰRŐ, EGYEDI és SORBA.RENDEZ függvénnyel egyetlen képletet ír, amely elkészíti a teljes listát, és magától frissül. Az Euro-Office ismeri ezeket az úgynevezett dinamikus tömböket: az eredmény annyi cellára „ömlik ki”, amennyire szükség van.

Példaként a Bakkerij De Korenaar Bestellingen nevű munkalapját használjuk: az A oszlopban a dátum, a B-ben az ügyfél, a C-ben a termék, a D-ben az összeg, az E-ben pedig az, hogy ki van-e fizetve (ja vagy nee).

Egyedi, rendezett ügyféllista

Írja be a G2 cellába a =SORBA.RENDEZ(EGYEDI(SZŰRŐ(B2:B500;B2:B500<>""))) képletet, és nyomja meg az Enter billentyűt. Ennyi az egész: minden ügyfél egyszer szerepel, ábécérendben, egymás alatt a G2 cellától kezdve.

  • A SZŰRŐ(B2:B500;B2:B500<>"") kihagyja az üres sorokat. Így a tartományt bőven megadhatja a később érkező rendelések számára is.
  • Az EGYEDI eltávolítja az ismétlődéseket.
  • A SORBA.RENDEZ sorba rendezi őket.
Több cellára kiömlő egyedi ügyféllista
A képlet csak a G2 cellában található (1), lásd a szerkesztőlécet; az eredmény az utolsó ügyfélig ömlik ki, a 14. sorban szereplő Tandarts Bos is megjelenik

Ha egy új ügyféltől érkezik rendelés, például a 14. sorban Tandarts Bos, akkor az azonnal a megfelelő helyre kerül a listában. Ha módosítani szeretné a listát, az első cellában, a G2-ben lévő képletet változtassa meg.

Az e havi összes nyitott rendelés

A SZŰRŐ teljes sorokat is le tud kérni, több feltétellel:

=SZŰRŐ(A2:D500;(E2:E500="nee")*(A2:A500>=HÓNAP.UTOLSÓ.NAP(MA();-1)+1);"niets open")

  • Az első rész az, amit látni szeretne: az A, D oszlopok helyett pontosabban az A-tól a D-ig terjedő oszlopok.
  • A második rész a feltételek. Minden feltétel zárójelben áll. A közöttük lévő * jelentése és, a + jelentése vagy.
  • A HÓNAP.UTOLSÓ.NAP(MA();-1)+1 az aktuális hónap első napja.
  • A harmadik rész az a szöveg, amely akkor jelenik meg, ha nincs találat.
SZŰRŐ két feltétellel
Az e havi nyitott rendelések az I2 cellától kezdve; figyelje meg az L oszlop összegeit, amelyek dátumként jelennek meg

Figyelem: az Euro-Office a teljes eredményre az első oszlop számformátumát alkalmazza. Ha az eredmény dátummal kezdődik, akkor az utolsó oszlopban lévő összegek is dátumként jelennek meg: a 36,00 értékből 05-02-1900 lesz. Jelölje ki az eredmény adott oszlopát, és állítsa be saját maga a Pénznem vagy a Szám formátumot (lásd: Számok, dátumok és pénznemek formázása).

Rendezés és oszlopok kiválasztása

  • Összeg szerint, a legnagyobbal kezdve: =SORBA.RENDEZ(SZŰRŐ(A2:D500;E2:E500="nee");4;-1). A 4 az eredmény negyedik oszlopa, a -1 csökkenő sorrendet jelent.
  • Rendezés olyan oszlop szerint, amelyet nem jelenít meg: a =RENDEZÉS.ALAP.SZERINT(SZŰRŐ(B2:B500;E2:E500="nee");SZŰRŐ(D2:D500;E2:E500="nee");-1) csak az ügyfélneveket adja vissza, összeg szerint rendezve.
  • Csak az ügyfél és az összeg: =OSZLOPVÁLASZTÁS(SZŰRŐ(A2:D500;E2:E500="nee");2;4).

Valami útban van

Ha már van valami egy olyan cellában, ahová az eredménynek kerülnie kellene, a lista nem tud kiömleni. Az Excel ilyenkor a #SPILL! hibaértéket mutatja. Az Euro-Office ilyenkor üresen hagyja a képletet tartalmazó cellát; ha rákattint, szaggatott vonal jelzi azt a területet, ahová az eredmény kerülne. Ürítse ki az ezen a területen lévő cellákat, és a lista azonnal megjelenik. Ezért hagyjon szabad helyet az ilyen képletek alatt és mellett.

Kiömleni nem tudó eredmény
A G2 cellában lévő képlet (1) üres marad: a G4 cellában (2) lévő blokkade szöveg útban van. A szaggatott vonal mutatja, hová kerülne a lista

Számolás teljes oszlopokkal egyetlen képletben

Egyes képletek egyszerre egy teljes oszloppal számolnak, például a =SZUM(D2:D13*(E2:E13="nee")): ez az összes még ki nem fizetett rendelés összegét adja, itt 258,50. Az Euro-Office-ban az ilyen képlet egyszerűen az Enter billentyűvel működik. A teljes oszlopra vonatkozó, egy másik függvényen belüli HA függvényt tartalmazó képleteket, például a =NAGY(HA(B2:B37="Taart";C2:C37);1) képletet, az Euro-Office egyszerű Enter esetén nem számolja ki helyesen: #NUM! hibát vagy hibás számot kap. Az ilyen képletet a Ctrl+Shift+Enter billentyűkombinációval zárja le. A képlet ekkor kapcsos zárójelek {…} közé kerül, és a helyes eredményt adja. Gyakran HA nélkül, a SZŰRŐ függvénnyel is megoldható: =NAGY(SZŰRŐ(C2:C37;B2:B37="Taart");1).

Amire nincs lehetőség

  • A LET és a LAMBDA függvényt, valamint az ezekre épülő függvényeket, például a BYROW, MAP és GROUPBY függvényt, az Euro-Office nem ismeri. Az ilyen függvényeket tartalmazó Excel-fájl #NAME? hibát ad. Használjon segédoszlopot, vagy nézze meg a(z) Excel-formules met LET of LAMBDA: wat je in Euro-Office in plaats daarvan doet cikket, hogy mit tehet helyettük.
  • Az Excel 2019-et vagy régebbi verziót használó kollégák ezeknél a függvényeknél #NAME? hibát látnak.

Buktatók

  • A teljes oszlopok, például a B:B, lelassítják a képletet. Válasszon bőséges, rögzített tartományt, például a B2:B500 tartományt.
  • Ne használjon zárójel nélküli IGAZ vagy HAMIS értéket ezekben a képletekben; használja helyettük az 1 és 0 értéket, vagy a TRUE és FALSE értéket (lásd: Excel-függvények átvétele: a magyar függvénynevek és a pontosvessző).

Egy pillanat…

Domainek beállítása

Állítsa be domainenként a névszervereket, a tárhelyhez való kapcsolást és azt, hogy ki legyen a tulajdonos.

Domainek betöltése…